Ultrarelativistic spinning objects (gyratons) in non-local ghost-free gravity
Last edited by Jens Boos, Apr 14, 2020.

(* import CustomTicks package which can be downloaded here: http://github.com/mark-caprio/CustomTicks *)
<<CustomTicks`
SetDirectory[NotebookDirectory[]];

Non-local Green functions in d ≥ 3

a[z_,ℓ_,N_]:=Exp[(-z ℓ^2)^N];
𝒢[r_,d_,ℓ_,N_]:=1/(2π)^(d/2)/r^(d-2)Integrate[ζ^(d/2-2)/a[-ζ^2/r^2,ℓ,N]BesselJ[d/2-1,ζ],{ζ,0,∞},Assumptions->{ℓ≥0,d∈Integers,d≥3,r≥0,N∈Integers,N>0}]

Gravitomagnetic charges in d=3

(* linearized General Relativity *)
GR4[r_] :=Limit[𝒢[r,4,ℓ,1],ℓ->0,Assumptions->{r>0}]
GR4[r]

(* linearized GF1 *)
𝒢[r,4,ℓ,1]

(* linearized GF2 *)
𝒢[r,4,ℓ,2]

(* gravitomagnetic charges in GF1 and GF2 theory *)

Q[ρ_,ℓ_,N_]:=(4π^2 r^2𝒢[r,4,ℓ,N])/.r->ρ;
Q[ρ,ℓ,1]
Q[ρ,ℓ,2]

Q1[ρ_,ℓ_]:=1-(E^(-((ρ^2)/(4 (ℓ^2)))));
Q2[ρ_,ℓ_]:=1-HypergeometricPFQ[{},{(1/2),(1/2)},((ρ^4)/(256 (ℓ^4)))]+(((Sqrt[π]) (ρ^2) HypergeometricPFQ[{},{1,(3/2)},((ρ^4)/(256 (ℓ^4)))])/(8 (ℓ^2)));

p01[size_] := Plot[{1,Q1[ρ,1],Q2[ρ,1]},{ρ,0,12},
PlotRange->{0,1.3},
PlotStyle->{{Thickness[0.0025]},{Thickness[0.0025], Dashing[0.03]},{Thickness[0.0025], Dashing[0.01]},Automatic,{Gray}},
FrameStyle->{{Gray,AbsoluteThickness[2(size/800)]},{Gray,AbsoluteThickness[2(size/800)]},
			{Gray,AbsoluteThickness[2(size/800)]},{Gray,AbsoluteThickness[2(size/800)]}},
FrameTicksStyle->Directive[FontSize->25(size/800)],Frame->True,
FrameTicks->{{LinTicks[0,1.3,TickLabelStep->1,MajorTickLength->0.01,MinorTickLength->0.005],None},
			{LinTicks[0,12,TickLabelStep->2,MajorTickLength->0.01,MinorTickLength->0.005],None}},
GridLines->Automatic,
AspectRatio->0.6,
ImageSize->size];
p01[500]
Export["plot-q-v1.png",p01[2000]];